I was never able to get this AppleScript to work properly: it would go through its paces but produce a 0K file at the end.
Here's an AppleScript Folder Action that I managed to cobble together based on an Apple-provided example. I created a folder on my Desktop called "juice_convert" and attached this AppleScript Folder Action to it. The script will create two folders within this folder: Original Items and Converted for Juice Box. The script has been tested and runs under OS X 10.4.7 and I have successfully loaded pictures on my Juice Box after converting JPEG images using this script. The image scaling and cropping is handled by OS X 10.4.x's Image Events application. You will need to install ImageMagick 6.2.9 (I chose the binary installation) and update the AppleScript to the correct path for ImageMagick in order to convert the .gif file that Image Events produces into an .rgb file. Additionally, you will need to have the 24to12.pl script to convert the .gif file to the .jbp file. Make sure you chmod the perl script to be executable, and modify the AppleScript for the correct path to 24to12.pl as well.
The script follows.
Enjoy!
Josh
-- OS X AppleScript Folder Action
-- Converts various graphic formats to the .jbp format for use with Mattel's Juice Box
-- 2006, Josh Burker
property done_foldername : "Converted for Juice Box"
property originals_foldername : "Original Images"
property newimage_extension : "gif"
-- the list of file types which will be processed
-- eg: {"PICT", "JPEG", "TIFF", "GIFf"}
property type_list : {"JPEG", "GIFf", "PNGf", "PICT"}
-- since file types are optional in Mac OS X,
-- check the name extension if there is no file type
-- NOTE: do not use periods (.) with the items in the name extensions list
-- eg: {"txt", "text", "jpg", "jpeg"}, NOT: {".txt", ".text", ".jpg", ".jpeg"}
property extension_list : {"jpg", "jpeg", "GIF", "png", "pict", "pct", "rgb", "jbp"}
on adding folder items to this_folder after receiving these_items
tell application "Finder"
if not (exists folder done_foldername of this_folder) then
make new folder at this_folder with properties {name:done_foldername}
end if
set the results_folder to (folder done_foldername of this_folder) as alias
if not (exists folder originals_foldername of this_folder) then
make new folder at this_folder with properties {name:originals_foldername}
set current view of container window of this_folder to list view
end if
set the originals_folder to folder originals_foldername of this_folder
end tell
try
repeat with i from 1 to number of items in these_items
set this_item to item i of these_items
set the item_info to the info for this_item
if (alias of the item_info is false and the file type of the item_info is in the type_list) or (the name extension of the item_info is in the extension_list) then
tell application "Finder"
my resolve_conflicts(this_item, originals_folder, "")
set the new_name to my resolve_conflicts(this_item, results_folder, newimage_extension)
set the source_file to (move this_item to the originals_folder with replacing) as alias
end tell
process_item(source_file, new_name, results_folder)
end if
end repeat
on error error_message number error_number
if the error_number is not -128 then
tell application "Finder"
activate
display dialog error_message buttons {"Cancel"} default button 1 giving up after 120
end tell
end if
end try
end adding folder items to
on resolve_conflicts(this_item, target_folder, new_extension)
tell application "Finder"
set the file_name to the name of this_item
set file_extension to the name extension of this_item
if the file_extension is "" then
set the trimmed_name to the file_name
else
set the trimmed_name to text 1 thru -((length of file_extension) + 2) of the file_name
end if
if the new_extension is "" then
set target_name to file_name
set target_extension to file_extension
else
set target_extension to new_extension
set target_name to (the trimmed_name & "." & target_extension) as string
end if
if (exists document file target_name of target_folder) then
set the name_increment to 1
repeat
set the new_name to (the trimmed_name & "." & (name_increment as string) & "." & target_extension) as string
if not (exists document file new_name of the target_folder) then
-- rename to conflicting file
set the name of document file target_name of the target_folder to the new_name
exit repeat
else
set the name_increment to the name_increment + 1
end if
end repeat
end if
end tell
return the target_name
end resolve_conflicts
-- this sub-routine processes files
on process_item(source_file, new_name, results_folder)
-- NOTE that the variable this_item is a file reference in alias format
-- FILE PROCESSING STATEMENTS GOES HERE
try
-- the target path is the destination folder and the new file name
set the target_path to ((results_folder as string) & new_name) as string
with timeout of 900 seconds
tell application "Image Events"
launch -- always use with Folder Actions
set this_image to open file (source_file as string)
scale this_image to size 240
-- scale the image
crop this_image to dimensions {240, 160}
-- save the image
save this_image as GIF in file target_path with icon
close this_image
end tell
end timeout
set target_path to POSIX path of target_path
do shell script "export MAGICK_HOME='/Applications/ImageMagick-6.2.9'; export DYLD_LIBRARY_PATH='$MAGIC_HOME/lib'; /Applications/ImageMagick-6.2.9/bin/convert '" & target_path & "' 'rgb:" & target_path & ".rgb'"
do shell script "/usr/local/bin/24to12.pl '" & target_path & ".rgb' '" & target_path & ".jbp'"
on error error_message
tell application "Finder"
activate
display dialog error_message buttons {"Cancel"} default button 1 giving up after 120
end tell
end try
end process_item
